Heute war ich produktiv! Anbei ein Script womit ihr euren Proxy bequem einstellen könnt:

@echo off
:start
cls
echo.
echo  Proxyeinstellungen
echo ~~~~~~~~~~~~~~~~~~~~~
echo Proxy aktivieren:   1
echo Proxy deaktivieren: 2
echo Proxy Status:       3
echo Help:               4
echo Programm beenden:   5
echo.
set /p menue="Bitte Aktionsnummer eingeben: "
if "%menue%" == "1" goto activate
if "%menue%" == "2" goto deactivate
if "%menue%" == "3" goto show
if "%menue%" == "4" goto help
if "%menue%" == "5" exit
goto start

:help
cls
echo.
echo Geschrieben von: Jens Willmer ([email protected])
echo.
echo Falls das Programm auf Windows 7 nicht funktioniert versuchen
echo Sie bitte die Eingabeaufforderung mit Administratorrechten
echo zu starten.
echo.
pause
goto start

:activate
cls
echo.
set /p proxy="Bitte Proxyname eingeben: "
if "%proxy%" == "" goto activate

:port
cls
echo.
set /p port="Bitte Port eingeben: "
if "%port%" == "" goto port
set #=%port%
set length=0

:loop
if defined # (set #=%#:~1%&set /A length += 1&goto loop)
if %length% GTR 5 goto error
cls
echo.
netsh winhttp set proxy %proxy%:%port%
echo.
pause
goto start

:error
cls
echo.
echo Port ist zu lang, bitte kleineren Port eingeben.
echo.
pause
goto port

:deactivate
netsh winhttp reset proxy
cls
echo.
echo Proxy wurde deaktiviert!
echo.
pause
goto start

:show
cls
echo.
netsh winhttp show proxy
echo.
pause
goto start