Windows 7 besitzt von Haus aus einen virtuellen Wifi-Netzwerkadapter mit welchem es möglich ist seinen Rechner in einen Access Point zu verwandeln. Damit das komfortabel von statten gehen kann habe ich euch ein kleines Kommandozeilen-Programm geschrieben.

Wichtig: Nach der Konfiguration in den Einstellungen auf den Lanadapter klicken welcher die Verbindung bereitstellen soll und in den Einstellungen unter Freigabe die eingerichtete Drahtlosverbindung zur gemeinsamen Nutzung auswählen. Und immer daran denken die CMD mit maximalen Rechten starten ;-)

Have Fun ;–)

:start
@echo off
cls
echo.
echo   WLAN Access Point
echo ~~~~~~~~~~~~~~~~~~~~~
echo WLAN aktivieren:    1
echo WLAN deaktivieren:  2
echo WLAN konfigurieren: 3
echo Help:               4
echo Programm beenden:   5
echo.
set /p menue="Bitte Aktionsnummer eingeben: "
if "%menue%" == "1" goto activate
if "%menue%" == "2" goto deactivate
if "%menue%" == "3" goto config
if "%menue%" == "4" goto help
if "%menue%" == "5" exit
goto start

:help
cls
echo.
echo Geschrieben von: Jens Willmer (info[at}jwillmer.de)
echo.
echo Falls das Programm auf Windows 7 nicht funktioniert versuchen
echo Sie bitte die Eingabeaufforderung mit Administratorrechten
echo zu starten.
echo.
pause
goto start

:config
cls
echo.
set /p pw="Bitte WLAN-Passwort eingeben: "
if "%pw%" == "" goto exceptPW
goto setSSID

:exceptPW
cls
echo.
echo Das WLAN wird nicht durch ein Passwort geschuetzt!
echo.
echo Passworteingabe wiederholen: 1
echo Ohne Passwort fortsetzen:    2
echo Zurueck zum Menue:           3
echo Programm beenden:            4
echo.
set /p exceptPW="Bitte Aktionsnummer eingeben: "
if "%exceptPW%" == "1" goto config
if "%exceptPW%" == "2" goto setSSID
if "%exceptPW%" == "3" goto start
if "%exceptPW%" == "4" exit
goto exceptPW

:setSSID
echo.
set /p ssid="Bitte SSID eingeben: "
if "%ssid%" == "" goto setSSID
if "%pw%" == "" goto openWlan
goto secureWlan

:openWlan
netsh wlan set hostednetwork key= keyUsage=persistent ssid=%ssid%
cls
echo.
echo Der WLAN Access Point mit der SSID: %ssid% wurde eingerichtet.
echo.
pause
goto start

:secureWlan
netsh wlan set hostednetwork key=%pw% keyUsage=persistent ssid=%ssid%
cls
echo.
echo Der WLAN Access Point mit der SSID: %ssid% wurde eingerichtet.
echo.
pause
goto start

:activate
cls
echo.
netsh wlan start hostednetwork
echo.
echo Um die Internetverbindung eines anderen Netzwerkadapters
echo zu verwenden muss diese in den Einstellungen des Adapters
echo fuer unseren Netzwerkadapter freigegeben werden!
echo.
pause
goto start

:deactivate
cls
echo.
netsh wlan stop hostednetwork
echo.
pause
goto start